鄙人原贴：http://www.bathome.net/thread-75743-1-1.html

@echo off
Set "zm=HKEY_CLASSES_ROOT\DesktopBackground\shell\zm"
Set "zms=%zm%\Shell"
Set "R=Call;:RZMY"
%R% "%zm%" "我的设置" "SHELL32.dll,-022" "0" "1"
%R% "%zms%\1" " 注册表" "regedit.exe" "regedit"
%R% "%zms%\2"  " 组策略" "gpedit.dll,0" "mmc gpedit.msc"
%R% "%zms%\3" " 计算器" "win32calc.exe" "calc"
%R% "%zms%\4" "桌面图标" "SHELL32.dll,34" "rundll32 shell32.dll,Control_RunDLL desk.cpl,,0" "1"
%R% "%zms%\5" "控制面板" "control.exe" "control.exe"
%R% "%zms%\6" "程序卸载" "OptionalFeatures.exe" "rundll32.exe shell32.dll,Control_RunDLL appwiz.cpl"
%R% "%zms%\7" "系统服务" "filemgmt.dll,0" "MMC services.msc" "1"
%R% "%zms%\8" "桌面截屏" "shell32.dll,238" "explorer ms-screenclip:"
%R% "%zms%\9" "系统版本" "shell32.dll,277" "winver.exe"
exit
:RZMY
if not "%~2"=="" Reg add "%~1" /f /v "MUIVerb" /t REG_SZ /d "%~2"
if not "%~3"=="" Reg add "%~1" /f /v "Icon" /t REG_SZ /d "%~3"
if "%~4"=="0" (Reg add "%~1" /f /v "SubCommands"
if "%~5"=="0" Reg add "%~1" /f /v "Position" /t REG_SZ /d "top"
if "%~5"=="1" Reg add "%~1" /f /v "Position" /t REG_SZ /d "Bottom" ) else (
if not "%~4"=="0" Reg add "%~1\Command" /f /ve /t REG_SZ /d "%~4")
if "%~5"=="1" Reg add "%~1" /f /v "CommandFlags" /t REG_DWORD /d "32"
Goto;:Eof

代码存 ANSI 编码，XXX.BAT，，，

-------卸载注册表命令，，，

Reg delete "HKEY_CLASSES_ROOT\DesktopBackground\shell\zm" /f

REG 注册表命令写法，都是 一行一命令，，一行一写法，，

所以我把该有的写法，集合在一个标签里调用，，，
采用参数调度，，，一行命令 搞定，，，

以实用命令解释：%R% "%zms%\1" "注册表" "regedit.exe" "regedit"

%R% 实际调用的是 执行 Call   调用脚本内部标签  :RZMY 

参数一 ："%zms%\1" 在变量里 写入的是 注册表路径 HKEY_CLASSES_ROOT\DesktopBackground\shell\zm\1

实际执行： Reg add "HKEY_CLASSES_ROOT\DesktopBackground\shell\zm\1" /f

参数二："注册表"  显示名称  "注册表"

实际执行： Reg add "HKEY_CLASSES_ROOT\DesktopBackground\shell\zm\1" /f /v "MUIVerb" /t REG_SZ /d "注册表"

参数三："regedit.exe"  显示图标，取至 "regedit.exe" 原程序，，

实际执行：Reg add "HKEY_CLASSES_ROOT\DesktopBackground\shell\zm\1" /f /v "Icon" /t REG_SZ /d "regedit.exe" 

参数四："regedit"  执行命令  "regedit" 

实际执行：Reg add "HKEY_CLASSES_ROOT\DesktopBackground\shell\zm\1\Command" /f /ve /t REG_SZ /d "regedit"

--------------------------------------

脚本只适用 WIN7以后的操作系统！XP系统没有右键折叠项。要另写 DLL ，，，不会！