如题：隐藏盘符.BAT（注册表障眼法）....WIN10可用版！
逛无忧，，看到一帖 ，，隐藏盘符.BAT（注册表障眼法），，，http://wuyou.net/forum.php?mod=viewthread&tid=449148&extra=page%3D1
后来试用了一下，发现WIN10 系统下并不能正藏隐藏，，也不知道那楼主用的是什么系统，，，

后来鄙人无聊就顺着他那思路修改了他的代码，并重构了计算方式，，，，
这个帖子发出来的是全新修改 WIN10 可用版的，，，，扔代码。

@Echo off 
Set 字母列表=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z
For %%a in (%字母列表%) do ( dir %%a: >nul 2>nul &&Call Set "盘符列表=%%盘符列表%% %%a")
If "%盘符列表:~0,1%"==" " Set 盘符列表=%盘符列表:~1%
:隐藏盘符输入
Set 盘符输入=
Set/p 盘符输入=输入【%盘符列表%】，输入【DEL】清除所有隐藏:
Cls
If /i "%盘符输入%"=="del" Reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v "NoDrives"  /f & cls &Echo.已清除所有隐藏盘符，按任意键重启Explorer进程！& Pause > Nul & Tskill Explorer & Start Explorer ::{20D04FE0-3AEA-1069-A2D8-08002B30309D} & Exit
Set 盘符输入=%盘符输入: =%
Set 输入检测=%盘符输入%
:隐藏盘符检测
Echo.%输入检测:~0,1%|findstr /i "%盘符列表%" >nul 2>nul ||Echo.【%输入检测:~0,1%】不在磁盘列表中，请重新输入 ！&& Goto,隐藏盘符输入
Set 输入检测=%输入检测:~1%
If Not "%输入检测%"=="" Goto,隐藏盘符检测
For %%b in (%字母列表%) do ( Call Set "_%%b=")
:拆分盘符
If Not Defined _%盘符输入:~,1% Set "_%盘符输入:~,1%=1"
Set "盘符输入=%盘符输入:~1%"
If Defined 盘符输入 Goto,拆分盘符
For %%c in (%字母列表%) do ( 
If Not Defined Nums (Set Nums=1) else (Call Set/a Nums*=2)
If Defined _%%c (Set/a 输入个数+=1
Call Set "盘符输入=%%盘符输入%%%%c,"
Call Set/a Num=Num+Nums))
:十六进制换算
Set /a Hex=Num %% 16
Set /a Num=Num / 16
If %Hex% equ 10 Set Hex=A
If %Hex% equ 11 Set Hex=B
If %Hex% equ 12 Set Hex=C
If %Hex% equ 13 Set Hex=D
If %Hex% equ 14 Set Hex=E
If %Hex% equ 15 Set Hex=F
Call Set Hexs=%%Hex%%%%Hexs%%
If %Num% Gtr 0 Goto,:十六进制换算
If "%盘符输入:~-1,1%"=="," Set 盘符输入=%盘符输入:~0,-1%
Echo.
Echo 要隐藏的磁盘有【%盘符输入%】共[%输入个数%]个盘!
Echo.&Echo.注册表代码：&Echo.Reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v "NoDrives" /t REG_DWORD /d "0x%Hexs%" /f
Echo.&Echo.按任意键，隐藏磁盘【%盘符输入%】，并重启Explorer进程。
Pause > Nul
Reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v "NoDrives" /t REG_DWORD /d "0x%Hexs%" /f
Tskill Explorer & Start Explorer ::{20D04FE0-3AEA-1069-A2D8-08002B30309D}
Pause > Nul & Exit

代码存 ANSI 编码，隐藏盘符.BAT
------------------------------
我这个写的版本，针对现有盘符才可选择，，，否则不可取。
而且把很多没必要多余的标签取消了，，，
代码变量&标签 尽可能写中文，取代注释，方便新手学习借鉴。
也取消了 延迟开关，，（不知道为什么我写代码很不喜欢开启延迟变量，尽量Call 调用（个人怪癖）），，，

欢迎大家对比测试各个系统下的运行结果，回来讨论，，，古董本，没装虚拟机，，，
也欢迎各路大神 对比一下我与无忧论坛发布的那代码的区别与不同。

---------清除隐藏盘符---保命代码。牢记

Reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v "NoDrives"  /f

--------送一条：无责隐藏所有盘符 A-Z-注册表（只在WIN10测试通过）

Reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v "NoDrives" /t REG_DWORD /d "0x3FFFFFF" /f

该贴首发于 批处理之家 http://www.bathome.net/thread-75763-1-1.html